Botpack
Class ChallengeDominationHUD

Core.Object
   |
   +--Engine.Actor
      |
      +--Engine.HUD
         |
         +--Botpack.ChallengeHUD
            |
            +--Botpack.ChallengeTeamHUD
               |
               +--Botpack.ChallengeDominationHUD

00001	//=============================================================================
00002	// ChallengeDominationHUD.
00003	//=============================================================================
00004	class ChallengeDominationHUD extends ChallengeTeamHUD;
00005	
00006	simulated function PostRender( canvas Canvas )
00007	{
00008		local int TeamScore;
00009		local int X, Y;
00010		local float XL, YL;
00011		local ControlPoint CP;
00012		local NavigationPoint N;
00013		local Texture CPTexture;
00014	
00015		Super.PostRender( Canvas );
00016	
00017		if ( bHideHud 
00018			|| ((Canvas.ClipX <= 400) && ((PlayerPawn(Owner).bShowScores) || bForceScores)) )
00019			return;
00020	
00021		if ( TournamentConsole(PlayerPawn(Owner).Player.Console).bShowSpeech == True )
00022			return;
00023	
00024		X = 0;
00025		Y = Canvas.ClipY - 384 * Scale;
00026		Canvas.Style = Style;
00027		Canvas.Font = MyFonts.GetSmallFont( Canvas.ClipX );
00028	
00029		for ( N=Level.NavigationPointList; N!=None; N=N.NextNavigationPoint )
00030			if ( N.IsA('ControlPoint') )
00031			{
00032				CP = ControlPoint(N);
00033				if (CP.ControllingTeam != None) 
00034					CPTexture = TeamIcon[CP.ControllingTeam.TeamIndex];
00035				else
00036					CPTexture = texture'I_TeamN';
00037	
00038				Canvas.DrawColor = BaseColor;
00039				Canvas.SetPos(X,Y);
00040				Canvas.DrawIcon(CPTexture, Scale);
00041				Y -= 140 * Scale;
00042			}
00043	
00044		// separate name drawing to reduce texture changes
00045		Y = Canvas.ClipY - 384 * Scale;
00046		for ( N=Level.NavigationPointList; N!=None; N=N.NextNavigationPoint )
00047			if ( N.IsA('ControlPoint') )
00048			{
00049				CP = ControlPoint(N);
00050				if (CP.ControllingTeam != None) 
00051					Canvas.DrawColor = TeamColor[CP.ControllingTeam.TeamIndex];
00052				else
00053					Canvas.DrawColor = WhiteColor;
00054				Canvas.SetPos(0, 0);
00055				Canvas.StrLen(CP.PointName, XL, YL);
00056				Canvas.SetPos(0, Y + 96 * Scale - YL);
00057				Canvas.DrawText(CP.PointName);
00058				Y -= 140 * Scale;
00059			}
00060	}
00061	
00062	simulated function bool SpecialIdentify(Canvas Canvas, Actor Other )
00063	{
00064		local float XL, YL;
00065	
00066		if ( !Other.IsA('ControlPoint') )
00067			return false;
00068	
00069		Canvas.Font = MyFonts.GetSmallFont( Canvas.ClipX );
00070		Canvas.DrawColor = RedColor;
00071		Canvas.DrawColor.R = 255 * (IdentifyFadeTime / 3.0);
00072	
00073		Canvas.StrLen(ControlPoint(Other).PointName, XL, YL);
00074		Canvas.SetPos(Canvas.ClipX/2 - XL/2, Canvas.ClipY - 74);
00075		Canvas.DrawText(ControlPoint(Other).PointName);
00076	
00077		return true;
00078	}
00079	
00080	defaultproperties
00081	{
00082	     ServerInfoClass=Class'Botpack.ServerInfoDOM'
00083	}